Precision:=Exact

PrecisionDigits:=6

Notation:=Rational

NotationDigits:=6

Branch:=Principal

Exponential:=Auto

Logarithm:=Auto

Trigonometry:=Auto

Trigpower:=Auto

Angle:=Radian

VariableOrder:=[x,y,z]

OutputBase:=Decimal

InputBase:=Decimal

InputMode:=Character

CaseMode:=Insensitive

DisplayFormat:=Normal

TimesOperator:=Dot

Precision:=Exact

PrecisionDigits:=6

Notation:=Rational

NotationDigits:=6

Branch:=Principal

Exponential:=Auto

Logarithm:=Auto

Trigonometry:=Auto

Trigpower:=Auto

Angle:=Radian

VariableOrder:=[x,y,z]

OutputBase:=Decimal

InputBase:=Decimal

InputMode:=Character

CaseMode:=Insensitive

DisplayFormat:=Normal

TimesOperator:=Dot

"*****************************************************"

"GEOMET7.MTH (Es necesario cargar antes de este fichero VECTOR.MTH y despues ~
este)"

"Experimentando el teorema de Morley."

"********************************************************"

"Un triangulo bastante irregular"

[[0,0],[6,0],[4,4],[0,0]]

"*****************************************************"

"ALGUNAS FUNCIONES PREPARATORIAS"

"****************************************************"

INTERSECCIONRECTAS(m,n,p,q,r,s):=[[m,n],[q,r]]^(-1)*[-p,-s]

"****************************************************"

"De forma cartesiana a forma compleja y viceversa"

FC(v):=v SUB 1+#i*v SUB 2

FV(z):=[RE(z),IM(z)]

COEFRECTA(a,m):=[m SUB 2-a SUB 2,a SUB 1-m SUB 1,a SUB 2*(m SUB 1-a SUB 1)-a ~
SUB 1*(m SUB 2-a SUB 2)]

"*****************************************************"

"Obteniendo las trisectrices en un triangulo"

"TRISAB(a,b,c) (a,b,c, son los vertices) nos proporciona la trisectriz del an~
gulo en A adyacente al lado b."

TRISAB(a,b,c):=COEFRECTA(a,FV(FC(a)+3*(FC(b)-FC(a))*#e^(#i/3*(PHASE(FC(c)-FC(~
a))-PHASE(FC(b)-FC(a))))))

TRISAC(a,b,c):=COEFRECTA(a,FV(FC(a)+3*(FC(b)-FC(a))*#e^(2*#i/3*(PHASE(FC(c)-F~
C(a))-PHASE(FC(b)-FC(a))))))

TRISBC(a,b,c):=TRISAB(b,c,a)

TRISBA(a,b,c):=TRISAC(b,c,a)

TRISCA(a,b,c):=TRISAB(c,a,b)

TRISCB(a,b,c):=TRISAC(c,a,b)

"*****************************************************"

"MACROTRIS(a,b,c) nos da las trisectrices del triangulo de vertices a,b,c"

MACROTRIS(a,b,c):=[[a,b,c,a],TRISAB(a,b,c),TRISAC(a,b,c),TRISBC(a,b,c),TRISBA~
(a,b,c),TRISCA(a,b,c),TRISCB(a,b,c)]

MACROTRIS(a,b,c):=[[a,b,c,a],TRISAB(a,b,c)*[x,y,1]=0,TRISAC(a,b,c)*[x,y,1]=0,~
TRISBC(a,b,c)*[x,y,1]=0,TRISBA(a,b,c)*[x,y,1]=0,TRISCA(a,b,c)*[x,y,1]=0,TRISC~
B(a,b,c)*[x,y,1]=0]

"*****************************************************"

"Un ejemplo para calcular y dibujar"

MACROTRIS([0,0],[6,0],[4,4])

"*****************************************************"

"MORLEYA(a,b,c) nos da el vertice del triangulo de Morley cercano al primer v~
ertice"

MORLEYA(a,b,c):=INTERSECCIONRECTAS((TRISBC(a,b,c)) SUB 1,(TRISBC(a,b,c)) SUB ~
2,(TRISBC(a,b,c)) SUB 3,(TRISCB(a,b,c)) SUB 1,(TRISCB(a,b,c)) SUB 2,(TRISCB(a~
,b,c)) SUB 3)

MORLEYA([0,0],[6,0],[4,4])

;Expd(#35)
[4.10786,1.7211]

MORLEYB(a,b,c):=MORLEYA(b,c,a)

MORLEYC(a,b,c):=MORLEYA(c,a,b)

"*****************************************************"

"MACROMORLEY(a,b,c) nos proporciona ya el triangulo de Morley"

MACROMORLEY(a,b,c):=[[a,b,c,a],[MORLEYA(a,b,c),MORLEYB(a,b,c),MORLEYC(a,b,c),~
MORLEYA(a,b,c)]]

"*****************************************************"

"DIVERSOS EXPERIMENTOS"

"PARA JUGAR UN POCO CON EL TEOREMA DE MORLEY"

MACROMORLEY([0,0],[6,0],[4,4])

MACROMORLEY([-3,-2],[6,0],[4,4])

VECTOR(MACROMORLEY([-3+0.1*t,-2+0.3*t],[6+0.2*t,0+0.5*t],[4-0*3*t,4+0.2*t]),t~
,1,10)

MACROTRIS([-3,-2],[6,0],[4,4])

MACROTRIS([-2.7,-1.1],[6.6,1.5],[4,4.6])

"Vamos a experimentar MORLEY con el y con giros de el"

MATRIZGIRO(t):=[[COS(t),-SIN(t)],[SIN(t),COS(t)]]

VECTOR(MACROMORLEY(MATRIZGIRO(t)*[0,0],MATRIZGIRO(t)*[3,0],MATRIZGIRO(t)*[SQR~
T(3)/2+3/2,SQRT(3)/2+3/2]),t,0,2*pi,1)

"Es interesante representar esto y ver como el triangulo"

"de Morley que he definido, siempre equilatero, pasa de ser"

"interno a ser parcialmente externo"

"*****************************************************"

MACROMORLEY([-3,-2],[6,0],[4,4])

VECTOR(MACROMORLEY([0+0.2*t,5+0.3*t],[6+0.3*t,0-0.1*t],[4+0.3*t,4-0.1*t]),t,1~
,10,2)

MACROMORLEY([0,0],[8,1],[4,6])

"Parece que se obtiene asi una generalizacion del teorema de"

"Morley. Parece que se pueden tomar las simetricas de las trisectr"

"Experimentando varios triangulos de Morley girando un triangulo"

MACROTRIS([0,0],[8,1],[4,6])

VECTOR(MACROMORLEY([0+0.2*t,5+0.3*t],[6+0.3*t,0-0.1*t],[4+0.3*t,4-0.1*t]),t,1~
,20,1)

"++++++++++++++++++++++++++++++++++++++++++++++++++++++"

"Experimentando con las rectas que dividen el angulo en"

"5 partes iguales al modo del teorema de Morley"

QUINAB(a,b,c):=COEFRECTA(a,FV(FC(a)+3*(FC(b)-FC(a))*#e^(#i/5*(PHASE(FC(c)-FC(~
a))-PHASE(FC(b)-FC(a))))))

QUINAC(a,b,c):=COEFRECTA(a,FV(FC(a)+3*(FC(b)-FC(a))*#e^(4*#i/5*(PHASE(FC(c)-F~
C(a))-PHASE(FC(b)-FC(a))))))

QUINBC(a,b,c):=QUINAB(b,c,a)

QUINBA(a,b,c):=QUINAC(b,c,a)

QUINCA(a,b,c):=QUINAB(c,a,b)

QUINCB(a,b,c):=QUINAC(c,a,b)

MACROQUIN(a,b,c):=[[a,b,c,a],QUINAB(a,b,c),QUINAC(a,b,c),QUINBC(a,b,c),QUINBA~
(a,b,c),QUINCA(a,b,c),QUINCB(a,b,c)]

MACROQUIN(a,b,c):=[[a,b,c,a],QUINAB(a,b,c)*[x,y,1]=0,QUINAC(a,b,c)*[x,y,1]=0,~
QUINBC(a,b,c)*[x,y,1]=0,QUINBA(a,b,c)*[x,y,1]=0,QUINCA(a,b,c)*[x,y,1]=0,QUINC~
B(a,b,c)*[x,y,1]=0]

MACROQUIN([0,0],[6,0],[4,4])

QUINA(a,b,c):=INTERSECCIONRECTAS((QUINBC(a,b,c)) SUB 1,(QUINBC(a,b,c)) SUB 2,~
(QUINBC(a,b,c)) SUB 3,(QUINCB(a,b,c)) SUB 1,(QUINCB(a,b,c)) SUB 2,(QUINCB(a,b~
,c)) SUB 3)

QUINB(a,b,c):=QUINA(b,c,a)

QUINC(a,b,c):=QUINA(c,a,b)

MACROQUINPUNTOS(a,b,c):=[[a,b,c,a],[QUINA(a,b,c),QUINB(a,b,c),QUINC(a,b,c),QU~
INA(a,b,c)]]

MACROQUINPUNTOS([0,0],[6,0],[4,4])

VECTOR(MACROQUINPUNTOS([0-t,0+t],[6+0.5*t,0-3*t],[4-t,4+t]),t,1,5)

VECTOR(MACROQUINPUNTOS([4-t,3+t],[7+0.5*t,-2-3*t],[10-t,4+t]),t,1,5)

VECTOR(MACROQUINPUNTOS([4-t,3+t],[7+0.5*t,-2-3*t],[10-t,4+t]),t,1,20)

VECTOR(MACROQUINPUNTOS([0-t,5+t],[7+0.5*t,3-3*t],[-10-t,-4+t]),t,1,20)

VECTOR(MACROQUINPUNTOS([1-t,5+t],[-6+0.5*t,-3-3*t],[+5-t,-4+t]),t,1,20)

"Por algunos experimentos podria parecer que se obtiene"

"tambien aqui triangulos equilateros, pero por los ultimos experimentos"

"parece claro que no es asi"

"**********************************************************"

"Habra que ver si en el caso de las trisectrices EXTERIORES"

"se trata solo de un espejismo"

"*****************************************************"

VECTOR(MACROMORLEY([-1,1],[1,-1],[3*COS(t),3*SIN(t)]),t,0,2*pi,0.5)

VECTOR(PHASE(3*COS(t)+3*#i*SIN(t)),t,0,2*pi,0.8)

;Approx(#95)
[0,0.8,1.6,2.4,-3.08318,-2.28318,-1.48318,-0.683185]

"Esto pone en claro que PHASE da valores entre -pi y pi"

"y esta es la causa de que salgan los triangulos con"

"los vertices exteriores al triangulo original"

"pero, cuales son los triangulos que dibuja exactamente?"

"Bastara examinar ahora, a la luz de este hecho, la formula"

"que he escrito para las trisectrices."

MACROTRIS([-1,1],[1,-1],[3,0])

MACROMORLEY([-1,1],[1,-1],[3,0])

"Lo anterior es el triangulo de Morley, tal como lo tengo"

"formulado y si se representan estas dos cosas al tiempo"

"se ve lo que esta pasando, que puntos corresponden a que bisectrices."

"El que salga exterior se debe a la forma de PHASE."

"Pero parece que esto pone de manifiesto un teorema que"

"habra que demostrar."

"*******************************************************"

"El unico triangulo "*a*r*b*i*t*r*a*r*i*o*""

Precision:=Exact

"Si convenimos en que dos angulos, para ser visualmente"

"diferentes, deben diferir en al menos 15 grados, entonces el unico"

"triangulo arbitrario acutangulo es el que tiene"

"angulos de 45,60,75 grados"

"Lo vamos a construir"

INTERSECCIONRECTAS(TAN(pi/4),-1,0,-TAN(5*pi/12),-1,+3*TAN(5*pi/12))

;Expd(#119)
[SQRT(3)/2+3/2,SQRT(3)/2+3/2]

"Este es el unico triangulo acutangulo arbitrario, no isosceles, no rectangul~
o."

[[0,0],[3,0],[SQRT(3)/2+3/2,SQRT(3)/2+3/2],[0,0]]

"*******************************************************"

"****************************************************"

"Vamos a tratar de experimentar con un pequeno cambio en PHASE"

"Mira en GEOMET8.MTH porque GEOMET7.MTH se va haciendo mu largo"

"&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&"