Precision := Approximate

PrecisionDigits := 6

Notation := Scientific

NotationDigits := 6

Branch := Principal

Exponential := Auto

Logarithm := Auto

Trigonometry := Auto

Trigpower := Auto

Angle := Radian

VariableOrder := [x,y,z]

OutputBase := Decimal

InputBase := Decimal

InputMode := Character

CaseMode := Insensitive

DisplayFormat := Normal

TimesOperator := Dot

"GEOMET2.MTH Un ensayo con DERIVE de M. de G."

"Geometria del triangulo"

"*******************************************************"

"Lo que sigue es una coleccion de ordenes a fin de experimentar"

"algunas relaciones de la geometria del triangulo que tienen que ver"

"con bisectrices internas y externas, circunferencias inscrita, circunscrita,~
"

"exinscritas, circulo de los nueve puntos, hasta llegar"

"a poder descubrir, experimentando, el teorema de Feuerbach que afirma"

"que el circulo de los nueve puntos es tangente al circulo inscrito y"

"a los tres exinscritos. No hay mas que experimentar con"

"diversos triangulos y aparece clara la conjetura."

"Se han dejado algunos ejemplos para que experimentes inmediatamente"

"con las construcciones que se van haciendo"

"****************************************************"

"Las bisectrices internas y externas"

RECTA(a,b):=(x-a SUB 1)*(b SUB 2-a SUB 2)-(y-a SUB 2)*(b SUB 1-a SUB 1)=0

BISECTRIZINTERIOR1(a,b,c):=IF(-(a SUB 2*(b SUB 1-c SUB 1)+a SUB 1*(c SUB 2-b ~
SUB 2)+b SUB 2*c SUB 1-b SUB 1*c SUB 2)^2<0,((x-a SUB 1)*(b SUB 2-a SUB 2)-(y~
-a SUB 2)*(b SUB 1-a SUB 1))/((b SUB 2-a SUB 2)^2+(b SUB 1-a SUB 1)^2)^(1/2)+~
((x-a SUB 1)*(c SUB 2-a SUB 2)-(y-a SUB 2)*(c SUB 1-a SUB 1))/((c SUB 2-a SUB~
 2)^2+(c SUB 1-a SUB 1)^2)^(1/2)=0,((x-a SUB 1)*(b SUB 2-a SUB 2)-(y-a SUB 2)~
*(b SUB 1-a SUB 1))/((b SUB 2-a SUB 2)^2+(b SUB 1-a SUB 1)^2)^(1/2)-((x-a SUB~
 1)*(c SUB 2-a SUB 2)-(y-a SUB 2)*(c SUB 1-a SUB 1))/((c SUB 2-a SUB 2)^2+(c ~
SUB 1-a SUB 1)^2)^(1/2)=0)

BISECTRIZINTERIOR2(a,b,c):=BISECTRIZINTERIOR1(b,c,a)

BISECTRIZINTERIOR3(a,b,c):=BISECTRIZINTERIOR1(c,a,b)

"Con la funcion siguiente, dados los tres vertices del triangulo,"

"aparecen las tres bisectrices."

MACROBISECTRICES(a,b,c):=[[a,b,c,a],BISECTRIZINTERIOR1(a,b,c),BISECTRIZINTERI~
OR2(a,b,c),BISECTRIZINTERIOR3(a,b,c)]

MACROBISECTRICES([0,0],[2,3],[1,4])

"****************************************"

"La interseccion de dos rectas"

INTERSECCIONRECTAS(m,n,p,q,r,s):=IF(DET([[m,n],[q,r]])/=0,[[m,n],[q,r]]^(-1)*~
[-p,-s],"?")

INTERSECCIONRECTAS(3,2,1,5,6,7)

;Expd(#27)
[1,-2]

MACROINTERSECCIONRECTAS(m,n,p,q,r,s):=[m*x+n*y+p=0,q*x+r*y+s=0,INTERSECCIONRE~
CTAS(m,n,p,q,r,s)]

MACROINTERSECCIONRECTAS(1,2,1,0,1,3)

;Expd(#30)
[x+2*y+1=0,y+3=0,[5,-3]]

"********************************************************"

"El incentro de un triangulo"

COEFBISECTRIZINTERIOR1(a,b,c):=IF(-(a SUB 2*(b SUB 1-c SUB 1)+a SUB 1*(c SUB ~
2-b SUB 2)+b SUB 2*c SUB 1-b SUB 1*c SUB 2)^2<0,[-a SUB 2/SQRT(a SUB 2^2-2*a ~
SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)+b SUB 2/SQRT(a~
 SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)-a~
 SUB 2/SQRT(a SUB 2^2-2*a SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2~
+c SUB 1^2)+c SUB 2/SQRT(a SUB 2^2-2*a SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SU~
B 1+c SUB 2^2+c SUB 1^2),a SUB 1/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2~
*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)-b SUB 1/SQRT(a SUB 2^2-2*a SUB 2*b SUB ~
2+a SUB 1^2-2*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)+a SUB 1/SQRT(a SUB 2^2-2*a~
 SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2)-c SUB 1/SQRT(~
a SUB 2^2-2*a SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2),~
a SUB 2*b SUB 1/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB 1+~
b SUB 2^2+b SUB 1^2)-a SUB 1*b SUB 2/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1~
^2-2*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)+a SUB 2*c SUB 1/SQRT(a SUB 2^2-2*a ~
SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2)-a SUB 1*c SUB ~
2/SQRT(a SUB 2^2-2*a SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SU~
B 1^2)],[-1*a SUB 2/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SU~
B 1+b SUB 2^2+b SUB 1^2)+1*b SUB 2/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2~
-2*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)+1*a SUB 2/SQRT(a SUB 2^2-2*a SUB 2*c ~
SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2)-1*c SUB 2/SQRT(a SUB 2~
^2-2*a SUB 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2),1*a SUB~
 1/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB 1+b SUB 2^2+b S~
UB 1^2)-1*b SUB 1/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB ~
1+b SUB 2^2+b SUB 1^2)-1*a SUB 1/SQRT(a SUB 2^2-2*a SUB 2*c SUB 2+a SUB 1^2-2~
*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2)+1*c SUB 1/SQRT(a SUB 2^2-2*a SUB 2*c SU~
B 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2),a SUB 2*b SUB 1/SQRT(a S~
UB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB 1+b SUB 2^2+b SUB 1^2)-a S~
UB 1*b SUB 2/SQRT(a SUB 2^2-2*a SUB 2*b SUB 2+a SUB 1^2-2*a SUB 1*b SUB 1+b S~
UB 2^2+b SUB 1^2)-a SUB 2*c SUB 1/SQRT(a SUB 2^2-2*a SUB 2*c SUB 2+a SUB 1^2-~
2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2)+a SUB 1*c SUB 2/SQRT(a SUB 2^2-2*a SUB~
 2*c SUB 2+a SUB 1^2-2*a SUB 1*c SUB 1+c SUB 2^2+c SUB 1^2)])

COEFBISECTRIZINTERIOR2(a,b,c):=COEFBISECTRIZINTERIOR1(b,c,a)

COEFBISECTRIZINTERIOR3(a,b,c):=COEFBISECTRIZINTERIOR1(c,a,b)

MACROBISECTRICESINTERIORES(a,b,c):=[[a,b,c,a],COEFBISECTRIZINTERIOR1(a,b,c)*[~
x,y,1]=0,COEFBISECTRIZINTERIOR2(a,b,c)*[x,y,1]=0,COEFBISECTRIZINTERIOR3(a,b,c~
)*[x,y,1]=0]

MACROBISECTRICESINTERIORES([0,0],[2,3],[1,4])

"***************************************************"

"Ahora obtenemos el incentro, es decir el centro del circulo inscrito"

INCENTRO(a,b,c):=INTERSECCIONRECTAS((COEFBISECTRIZINTERIOR2(a,b,c)) SUB 1,(CO~
EFBISECTRIZINTERIOR2(a,b,c)) SUB 2,(COEFBISECTRIZINTERIOR2(a,b,c)) SUB 3,(COE~
FBISECTRIZINTERIOR1(a,b,c)) SUB 1,(COEFBISECTRIZINTERIOR1(a,b,c)) SUB 2,(COEF~
BISECTRIZINTERIOR1(a,b,c)) SUB 3)

INCENTRO([0,0],[2,3],[1,4])

INCENTRO([7,0],[2,2],[-3,-4])

"************************************************"

"El circulo inscrito"

CIRCULO(centro,radio):=(x-centro SUB 1)^2+(y-centro SUB 2)^2-radio^2=0

CIRCULO([0,1],2)

DISTANCIA(v,p,q):=ABS((v SUB 1-p SUB 1)*(q SUB 2-p SUB 2)-(v SUB 2-p SUB 2)*(~
q SUB 1-p SUB 1))/((q SUB 2-p SUB 2)^2+(q SUB 1-p SUB 1)^2)^(1/2)

INRADIO(a,b,c):=DISTANCIA(INCENTRO(a,b,c),b,c)

INRADIO([7,0],[2,2],[-3,-4])

CIRCULOINSCRITO(a,b,c):=CIRCULO(INCENTRO(a,b,c),INRADIO(a,b,c))

CIRCULOINSCRITO([7,0],[2,2],[-3,-4])

"*********************************************"

"Las bisectrices exteriores se encuentran facilmente"

COEFBISECTRIZEXTERIOR1(a,b,c):=[(COEFBISECTRIZINTERIOR1(a,b,c)) SUB 2,-(COEFB~
ISECTRIZINTERIOR1(a,b,c)) SUB 1,-(COEFBISECTRIZINTERIOR1(a,b,c)) SUB 2*a SUB ~
1+(COEFBISECTRIZINTERIOR1(a,b,c)) SUB 1*a SUB 2]

COEFBISECTRIZEXTERIOR2(a,b,c):=COEFBISECTRIZEXTERIOR1(b,c,a)

COEFBISECTRIZEXTERIOR3(a,b,c):=COEFBISECTRIZEXTERIOR1(c,a,b)

MACROBISECTRICESEXTERIORES(a,b,c):=[[a,b,c,a],COEFBISECTRIZEXTERIOR1(a,b,c)*[~
x,y,1]=0,COEFBISECTRIZEXTERIOR2(a,b,c)*[x,y,1]=0,COEFBISECTRIZEXTERIOR3(a,b,c~
)*[x,y,1]=0]

MACROBISECTRICESEXTERIORES([7,0],[2,2],[-3,-4])

"************************************************"

"Los circulos exinscritos"

EXCENTRO1(a,b,c):=INTERSECCIONRECTAS((COEFBISECTRIZINTERIOR1(a,b,c)) SUB 1,(C~
OEFBISECTRIZINTERIOR1(a,b,c)) SUB 2,(COEFBISECTRIZINTERIOR1(a,b,c)) SUB 3,(CO~
EFBISECTRIZEXTERIOR2(a,b,c)) SUB 1,(COEFBISECTRIZEXTERIOR2(a,b,c)) SUB 2,(COE~
FBISECTRIZEXTERIOR2(a,b,c)) SUB 3)

EXCENTRO2(a,b,c):=EXCENTRO1(b,c,a)

EXCENTRO3(a,b,c):=EXCENTRO1(c,a,b)

CIRCULOEXINSCRITO1(a,b,c):=CIRCULO(EXCENTRO1(a,b,c),DISTANCIA(EXCENTRO1(a,b,c~
),b,c))

CIRCULOEXINSCRITO2(a,b,c):=CIRCULOEXINSCRITO1(b,c,a)

CIRCULOEXINSCRITO3(a,b,c):=CIRCULOEXINSCRITO1(c,a,b)

"*************************************************"

"El circulo circunscrito"

COEFMEDIATRIZ(a,b):=[b SUB 1-a SUB 1,b SUB 2-a SUB 2,(a SUB 1^2+a SUB 2^2-b S~
UB 1^2-b SUB 2^2)/2]

CIRCUNCENTRO(a,b,c):=INTERSECCIONRECTAS((COEFMEDIATRIZ(a,b)) SUB 1,(COEFMEDIA~
TRIZ(a,b)) SUB 2,(COEFMEDIATRIZ(a,b)) SUB 3,(COEFMEDIATRIZ(b,c)) SUB 1,(COEFM~
EDIATRIZ(b,c)) SUB 2,(COEFMEDIATRIZ(b,c)) SUB 3)

CIRCULOCIRCUNSCRITO(a,b,c):=CIRCULO(CIRCUNCENTRO(a,b,c),ABS(CIRCUNCENTRO(a,b,~
c)-a))

CIRCULONUEVEPUNTOS(a,b,c):=CIRCULOCIRCUNSCRITO((a+b)/2,(b+c)/2,(c+a)/2)

RECTA(a,b):=(x-a SUB 1)*(b SUB 2-a SUB 2)-(y-a SUB 2)*(b SUB 1-a SUB 1)=0

"****************************************************"

"Asi se tienen los elementos para el teorema de Feuerbach"

MACROFEUERBACH(a,b,c):=[RECTA(a,b),RECTA(b,c),RECTA(c,a),CIRCULONUEVEPUNTOS(a~
,b,c),CIRCULOINSCRITO(a,b,c),CIRCULOEXINSCRITO1(a,b,c),CIRCULOEXINSCRITO2(a,b~
,c),CIRCULOEXINSCRITO3(a,b,c)]

MACROFEUERBACH([7,0],[0,2],[-3,-4])

MACROFEUERBACH([0,0],[3,1],[-1,-5])

MACROFEUERBACH([1,2],[-1,4],[2,-3])

"****************************************************"

"Los nueve puntos del circulo de Feuerbach"

COEFALTURA1(a,b,c):=[c SUB 1-b SUB 1,c SUB 2-b SUB 2,a SUB 1*(b SUB 1-c SUB 1~
)+a SUB 2*(b SUB 2-c SUB 2)]

COEFALTURA2(a,b,c):=COEFALTURA1(b,c,a)

COEFALTURA3(a,b,c):=COEFALTURA1(c,a,b)

ORTOCENTRO(a,b,c):=INTERSECCIONRECTAS((COEFALTURA1(a,b,c)) SUB 1,(COEFALTURA1~
(a,b,c)) SUB 2,(COEFALTURA1(a,b,c)) SUB 3,(COEFALTURA2(a,b,c)) SUB 1,(COEFALT~
URA2(a,b,c)) SUB 2,(COEFALTURA2(a,b,c)) SUB 3)

ORTOCENTRO([7,0],[0,2],[-3,-4])

;Expd(#87)
[-3/4,31/8]

RECTA(a,b):=(x-a SUB 1)*(b SUB 2-a SUB 2)-(y-a SUB 2)*(b SUB 1-a SUB 1)=0

COEFRECTA(a,b):=[b SUB 2-a SUB 2,-b SUB 1+a SUB 1,a SUB 1*(a SUB 2-b SUB 2)+a~
 SUB 2*(b SUB 1-a SUB 1)]

PIEDEALTURA1(a,b,c):=INTERSECCIONRECTAS((COEFALTURA1(a,b,c)) SUB 1,(COEFALTUR~
A1(a,b,c)) SUB 2,(COEFALTURA1(a,b,c)) SUB 3,(COEFRECTA(b,c)) SUB 1,(COEFRECTA~
(b,c)) SUB 2,(COEFRECTA(b,c)) SUB 3)

PIEDEALTURA2(a,b,c):=PIEDEALTURA1(b,c,a)

PIEDEALTURA3(a,b,c):=PIEDEALTURA1(c,a,b)

NUEVEPUNTOS(a,b,c):=[(a+b)/2,(b+c)/2,(c+a)/2,PIEDEALTURA1(a,b,c),PIEDEALTURA2~
(a,b,c),PIEDEALTURA3(a,b,c),(ORTOCENTRO(a,b,c)+a)/2,(ORTOCENTRO(a,b,c)+b)/2,(~
ORTOCENTRO(a,b,c)+c)/2]

TRIANGULOYCIRCULONUEVEPUNTOS(a,b,c):=[[a,b,c,a],CIRCULONUEVEPUNTOS(a,b,c)]

TRIANGULOYCIRCULONUEVEPUNTOS([0,0],[6,0],[5,4])

"******************************************************"