"GEOMET1.MTH Un ensayo con DERIVE de M. de G."

"Un programa para experimentar unas cuantas transformaciones en el plano"

"(Haria falta poner nombres mas abreviados, pero tal como estan ayudan a la m~
emoria)"

"**************************************************************"

Precision:=Exact

"Definimos unas cuantas transformaciones en el plano primero"

PUNTOMEDIO(a,b):=(a+b)/2

MEDIATRIZ(a,b):=(b-a) SUB 1*(x-((a+b)/2) SUB 1)+(b-a) SUB 2*(y-((a+b)/2) SUB ~
2)=0

RECTAPARALELA(m,n,p,v):=m*(x-v SUB 1)+n*(y-v SUB 2)=0

RECTAPERPENDICULAR(m,n,p,v):=n*(x-v SUB 1)-m*(y-v SUB 2)=0

RECTAPENDIENTEARECTACART(a,m):=IF(m=inf,x=a SUB 1,m*x-y-m*a SUB 1+a SUB 2=0)

RECTACARTAPUNTOPENDIENTE(m,n,p):=IF(n/=0,SOLVE(m*x+n*y+p=0,y),SOLVE(m*x+n*y+p~
=0,x))

NORMALUNITARIA(v,m,n,p):=IF(m*v SUB 1+n*v SUB 2+p>0,-1/(m^2+n^2)^(1/2)*[m,n],~
1/(m^2+n^2)^(1/2)*[m,n])

DISTANCIA(v,m,n,p):=ABS(m*v SUB 1+n*v SUB 2+p)/(m^2+n^2)^(1/2)

SIMETRICO(v,m,n,p):=v+2*DISTANCIA(v,m,n,p)*NORMALUNITARIA(v,m,n,p)

SIMETRICODEPUNTORESPECTOPUNTO(v,p):=2*p-v

SIMETRICOPUNTORESPECTORECTA(v,m,n,p):=[(v SUB 1*(n^2-m^2)-2*v SUB 2*m*n-2*p*m~
)/(m^2+n^2),(v SUB 2*(m^2-n^2)-2*v SUB 1*m*n-2*p*n)/(m^2+n^2)]

ROTACION(v,p,ang):=p+[(v SUB 1-p SUB 1)*COS(ang)-(v SUB 2-p SUB 2)*SIN(ang),(~
v SUB 1-p SUB 1)*SIN(ang)+(v SUB 2-p SUB 2)*COS(ang)]

INVERSODEVRESPECTOPPOTENCIAK(v,p,k):=p+k/ABS(v-p)^2*(v-p)

HOMOTETICODEVRESPECTOPRAZONK(v,p,k):=p+k*(v-p)

"*************************************************"

"Definicion de los macros para hacer las graficas mas comodas e ilustrativas"

F(x,y):=

MACROINVERSION(p,k):=[F(x,y),(x-p SUB 1)^2+(y-p SUB 2)^2-k=0,F((INVERSODEVRES~
PECTOPPOTENCIAK([x,y],p,k)) SUB 1,(INVERSODEVRESPECTOPPOTENCIAK([x,y],p,k)) S~
UB 2)]

MACROROTACION(c,alpha):=[F(x,y),c,F((ROTACION([x,y],c,-alpha)) SUB 1,(ROTACIO~
N([x,y],c,-alpha)) SUB 2)]

MACROSIMETRIARESPECTORECTA(m,n,p):=[F(x,y),m*x+n*y+p=0,F((SIMETRICOPUNTORESPE~
CTORECTA([x,y],m,n,p)) SUB 1,(SIMETRICOPUNTORESPECTORECTA([x,y],m,n,p)) SUB 2~
)]

MACROHOMOTECIA(p,k):=[F(x,y),p,F((HOMOTETICODEVRESPECTOPRAZONK([x,y],p,1/k)) ~
SUB 1,(HOMOTETICODEVRESPECTOPRAZONK([x,y],p,1/k)) SUB 2)]

"*******************************************************"

"COMO PROCEDER PARA EXPERIMENTAR"

"Ahora se puede proceder asi, para obtener los macros correspondientes"

"a MACROINVERSION, MACROHOMOTECIA, MACROROTACION,..."

"Definimos la curva que nos interese"

"F(x,y):=.....=0 (no olvidar el =0), y luego"

"MACROINVERSION(centro,potencia)  MACROHOMOTECIA(centro,razon)"

"MACROROTACION(centro,angulo)   MACROSIMETRIARESPECTORECTA(los tres coeficien~
tes de la recta)"

"Se aproxima y se representa"

"*********************************************************"

"EJEMPLOS"

"(Si los ejes se ponen del color del fondo queda mejor)"

"Se puede empezar experimentando con algo simple"

F(x,y):=x+2*y-1=0

MACROINVERSION([0,0],16)

MACROROTACION([3,5],pi/2)

MACROHOMOTECIA([2,2],3)

MACROSIMETRIARESPECTORECTA(5,4,1)

"La curva F(x,y) se puede elegir muy complicada. El precio"

"sera el tiempo para el dibujo."

"*******************************************************"