"GEOMET4.MTH Un ensayo con DERIVE de M. de G."

"Sobre lugares geometricos"

"************************************************"

"Lugar geometrico de los puntos tales que la suma de cuadrados"

"de distancias a dos puntos fijos a,b es constante k"

DISTANCIAPUNTOS(a,b):=((a SUB 1-b SUB 1)^2+(a SUB 2-b SUB 2)^2)^(1/2)

LGSUMASCUADRADOS(a,b,k):=DISTANCIAPUNTOS([x,y],a)^2+DISTANCIAPUNTOS([x,y],b)^~
2-k=0

LGSUMASCUADRADOS(a,b,k)

;Expd(#8)
a SUB 2^2-2*y*a SUB 2+a SUB 1^2-2*x*a SUB 1+b SUB 2^2-2*y*b SUB 2+b SUB 1^2-2~
*x*b SUB 1+2*x^2+2*y^2-k=0

"Esto pone en claro que se trata de una circunferencia"

"Se puede hacer un macro"

MACROLGSUMASCUADRADOS(a,b,k):=[[a,b],LGSUMASCUADRADOS(a,b,k)]

MACROLGSUMASCUADRADOS([0,1],[2,3],10)

"****************************************************"

"Si queremos su centro y su radio"

CENTROCIRCUNFERENCIA(m,p,q,s):=[-p/(2*m),-q/(2*m)]

RADIOCIRCUNFERENCIA(m,p,q,s):=(p^2+q^2-4*s*m)^(1/2)/(2*m)

CENTROCIRCUNFERENCIA(2,-2*a SUB 1-2*b SUB 1,-2*a SUB 2-2*b SUB 2,s)

;Expd(#18)
[a SUB 1/2+b SUB 1/2,a SUB 2/2+b SUB 2/2]

"El punto medio"

RADIOCIRCUNFERENCIA(2,-2*a SUB 1-2*b SUB 1,-2*a SUB 2-2*b SUB 2,a SUB 2^2+a S~
UB 1^2+b SUB 2^2+b SUB 1^2-k)

;Expd(#21)
SQRT(-a SUB 2^2+2*a SUB 2*b SUB 2-a SUB 1^2+2*a SUB 1*b SUB 1-b SUB 2^2-b SUB~
 1^2+2*k)/2

"Pero esta expresion no parece decir mucho"

"********************************************************"

LGDIFERENCIASCUADRADOS(a,b,k):=DISTANCIAPUNTOS([x,y],a)^2-DISTANCIAPUNTOS([x,~
y],b)^2-k=0

LGDIFERENCIASCUADRADOS([0,1],[2,5],5)

;Expd(#26)
4*x+8*y-33=0

"Aparece una recta. Asi es en general"

LGDIFERENCIASCUADRADOS(a,b,k)

;Expd(#29)
a SUB 2^2-2*y*a SUB 2+a SUB 1^2-2*x*a SUB 1-b SUB 2^2+2*y*b SUB 2-b SUB 1^2+2~
*x*b SUB 1-k=0

MACROLGDIFERENCIASCUADRADOS(a,b,k):=[[a,b],LGDIFERENCIASCUADRADOS(a,b,k)]

MACROLGDIFERENCIASCUADRADOS([0,2],[1,-1],7)

"**************************************************"

"Lugar de los puntos tales que la razon de las distancias"

"a dos puntos fijos a y b es constante"

LGRAZONDISTANCIAS(a,b,k):=DISTANCIAPUNTOS([x,y],a)-k*DISTANCIAPUNTOS([x,y],b)~
=0

LGRAZONDISTANCIAS(a,b,k)

;Expd(#37)
SQRT(a SUB 2^2-2*y*a SUB 2+a SUB 1^2-2*x*a SUB 1+x^2+y^2)-k*SQRT(b SUB 2^2-2*~
y*b SUB 2+b SUB 1^2-2*x*b SUB 1+x^2+y^2)=0

MACROLGRAZONDISTANCIAS(a,b,k):=[[a,b],LGRAZONDISTANCIAS(a,b,k)]

MACROLGRAZONDISTANCIAS([1,2],[3,3],3)

"***************************************************"

"Lugar de los puntos cuyas sumas de cuadrados de distancias"

"a dos rectas es constante"

DISTANCIAPUNTORECTA(a,m,n,p):=ABS(m*a SUB 1+n*a SUB 2+p)/(m^2+n^2)^(1/2)

LGSUMASCUADRADOSDISTANCIASADOSRECTAS(m,n,p,q,r,s,k):=DISTANCIAPUNTORECTA([x,y~
],m,n,p)^2+DISTANCIAPUNTORECTA([x,y],q,r,s)^2-k=0

MACROLGSUMASCUADRADOSDISTANCIASADOSRECTAS(m,n,p,q,r,s,k):=[m*x+n*y+p=0,q*x+r*~
y+s=0,LGSUMASCUADRADOSDISTANCIASADOSRECTAS(m,n,p,q,r,s,k)]

MACROLGSUMASCUADRADOSDISTANCIASADOSRECTAS(3,1,0,2,5,2,9)

"Aparece una elipse que es lo que va a salir en general"

LGSUMASCUADRADOSDISTANCIASADOSRECTAS(m,n,p,q,r,s,k)

"********************************************************"

"Lugar geometrico de los puntos cuyas sumas de distancias"

"a dos rectas es constante"

LGSUMASDISTANCIASADOSRECTAS(m,n,p,q,r,s,k):=DISTANCIAPUNTORECTA([x,y],m,n,p)+~
DISTANCIAPUNTORECTA([x,y],q,r,s)-k=0

LGSUMASDISTANCIASADOSRECTAS(3,1,0,2,5,2,9)

MACROLGSUMASDISTANCIASADOSRECTAS(m,n,p,q,r,s,k):=[m*x+n*y+p=0,q*x+r*y+s=0,LGS~
UMASDISTANCIASADOSRECTAS(m,n,p,q,r,s,k)]

MACROLGSUMASDISTANCIASADOSRECTAS(3,1,0,2,5,2,9)

"Un poco lento porque hay muchas raices, pero va bien"

"*******************************************************"

"Se puede hacer facilmente el lugar de los puntos cuya"

"razon de distancias a dos rectas es constante,...."

"*************************************************"